High Performance HMAC Cookie Signing

Problem this snippet solves:

General Information

The outlined iRule implements a Hash-based Message Authentication Code (see RFC 2104) cookie signing functionality, to provide an additional security layer for sensitive session cookie information.

The iRule computes an HMAC verification token based on X509 certificate- or TCP-Connection information and a given session cookie and then passes the results as an additional HTTP cookie to the client. If the HMAC cookie is missing on subsequent requests, or a mismatch between the X509 certificate-, TCP-Connection- or session cookie information and the HMAC verification token is identified, then the given session cookie would become silently removed from the HTTP request to the backend system. Thus would then result in re-initialization and/or a re-authentication of the user session on the backend.

Security benefits of HMAC cookie signing

The provided HMAC based cookie signing mechanism has some very unique advantages.

  1. Providing tamper resistance to cookie information without utilizing CPU intensive per-request cookie decryption.
  2. Transparently binding of X509 certificate information to sensitive session cookies, so that ANY KNOWN FORM of cookie hijacking on smartcard authenticated connections can be securely mitigated. Even those between two legitimate smartcard users!
  3. Transparently binding of client IP address or F5 GeoLocation information to sensitive session cookies, so that an additional protection layer against cookie hijacking or general misuse can be provided.

Performance consideration

The iRule is highly performance optimized to provide an as fast as possible request throughput. The iRule utilizes a RAM cache for previously calculated HMAC tokens, to shrink the required CPU cycles for the per-request cookie verification to an absolute minimum. The RAM caches are based on run-time modified

$static::variable(arrays)
to avoid any form of cross TMM communications and TMM connection parking situations like the
[table]
command would do, while still being fully CMP-compliant. The RAM caches are built and maintained on each TMM core independently and do support a
RULE_INIT
driven and also configurable garbage collection interval using the
[after -periodic]
syntax and a maximum cache size limiter to optimize and protect the memory/health of the plattform. When a garbage collection occurs, then all previously cached HMAC tokens are getting flushed as a whole and recalculated on demand without interrupting the active sessions.

The performance test used to measure and optimize the performance of the iRule was built on a two core LTM-1600 unit, with synthetically pre-filled RAM caches containing 100.000 unique HMAC tokens on each TMM core. The cookies where based on random ASP.NET session ids in combination with X509 CNAME information and resulted to a memory footprint of roughly 17,5 Mbyte per TMM core. The test scenario contains a single user session requesting consecutive 25 page impressions on a website with 40 web objects (1000 requests) using four independent HTTP keep-alive connections.

--------------------------------------------
Ltm::Rule Event: iRule_2_Delete:HTTP_REQUEST
--------------------------------------------
Priority                    500
Executions             
  Total                    1.0K
  Failures                    0
  Aborts                      0
CPU Cycles on Executing
  Average                 67.6K
  Maximum                189.4K
  Minimum                 27.2K

---------------------------------------------
Ltm::Rule Event: iRule_2_Delete:HTTP_RESPONSE
---------------------------------------------
Priority                   500
Executions             
  Total                   1.0K
  Failures                   0
  Aborts                     0
CPU Cycles on Executing
  Average                29.9K
  Maximum               212.6K
  Minimum                19.4K

Note: The rather high maximum CPU values are cause by a single

Set-Cookie
HMAC calculation in the
HTTP_RESPONSE
event, and an additional HMAC calculation on the second TMM core on its first
HTTP_REQUEST
event. Based on the differences of the Average and Maximum CPU cycles needed for the different code paths of the HMAC verification, the offloading factor of the RAM cache can be specified at round about 65% saved CPU cycles per
HTTP_REQUEST
event.

Credits

Special thanks goes to the DevCentral member Devon Twesten from "Booz Allen Hamilton", which came up with the idea of HMAC signing session cookies based on X509 certificate information as an additional protection layer. You may read his original posting here.

Cheers, Kai

How to use this snippet:

Usage:

  1. Create a new iRule and copy/paste the provided iRule into it.
  2. Identify your session cookie name and modify the
    RULE_INIT
    section to reflect your environment and configure the desired cache garbage collection interval and maximum cache size limits as needed.
  3. Modify the
    $hmac_input
    variable creation examples as needed to include X509 information, Client IP address or F5 GeoLocation information.
  4. Attach the iRule to your Vitual Server.
  5. Test the iRule by trying to modify the HMAC or session cookie.
  6. Keep an eye on the provided HMAC cache garbage collection log entires and tweak the garbage collection interval as needed.

Code :

#
# Deployment specific iRule events
#

# Note: Use just one of the outlined deployment specific iRule events. Combining them would be possible by changing [set hmac_input] to [append hmac_input], but it wouldn't make much sense to do so.

when CLIENT_ACCEPTED {
# log -noname local0.debug "HMAC: CLIENT_ACCEPTED: Setting client IP addr as HMAC token input."
set hmac_input [IP::client_addr]
}

when CLIENT_ACCEPTED {
# log -noname local0.debug "HMAC: CLIENT_ACCEPTED: Setting GeoLocation country data as HMAC token input."
set hmac_input [whereis [IP::client_addr] country]
} 

when CLIENTSSL_HANDSHAKE {
# log -noname local0.debug "HMAC: CLIENTSSL_HANDSHAKE: Checking if SSL handshake used client certificate."
if { ( [SSL::cert count] > 0 ) and ( [set x509_subject [X509::subject [SSL::cert 0]]] ne "" ) } then {
# log -noname local0.debug "HMAC: CLIENTSSL_HANDSHAKE: Setting the X509 subject name as HMAC token input."
if { [set hmac_input [X509::subject [SSL::cert 0]]] eq "" } then {
# log -noname local0.debug "HMAC: CLIENTSSL_HANDSHAKE: The certificate does not contain a X509 subject name. Rejecting the session..."
reject
}
} else {
# log -noname local0.debug "HMAC: CLIENTSSL_HANDSHAKE: The SSL handshake does not used any client certificate. Rejecting the session..."
reject
}
}

#
# HMAC verification related iRule events
#

when RULE_INIT {

# Modify the settings below to reflect your application and insert a strong enougth HMAC signing key. 

set static::hmac_signing_key "AzaZ5678901234567XYZ34567XYZ" ;# The HMAC256 signing key should be ideally a 256bit random key
set static::session_cookie "ASP.NET_SessionId";# Name of the Session Cookie
set static::hmac_cookie "ASP.NET_SessionId_HMAC";# Name of the HMAC Cookie
set static::hmac_cache_maxsize 100000;# Maximum number of HMAC cache entries per TMM core

# Initialize the HMAC cache array
unset -nocomplain static::hmac_cache
set static::hmac_cache(count) 0

# Tweak the -periodic interval of the HMAC garbage collection as needed (3600000 msec = 1hour, 86400000 msec = 1day) 
after 86400000 -periodic {
if { [array exists static::hmac_cache] } then {
log -noname local0.debug "HMAC: Cache Array Recycling: Clearing the HMAC cache array on TMM [TMM::cmp_unit] with currently $static::hmac_cache(count) entries"
unset -nocomplain static::hmac_cache
set static::hmac_cache(count) 0
}
}
}
when HTTP_REQUEST { 
if { [catch {
# log -noname local0.debug "HMAC: HTTP_REQUEST: Query the HMAC cache array on TMM[TMM::cmp_unit] for existence of pre-computed HMAC values."
if { $static::hmac_cache([HTTP::cookie value $static::session_cookie]:$hmac_input) eq [HTTP::cookie value $static::hmac_cookie] } then {
# log -noname local0.debug "HMAC: HTTP_REQUEST: HMAC cookie is verified using a cached HMAC token on TMM[TMM::cmp_unit]. Allowing the session cookie \"$static::session_cookie\" to pass."
} else {
# log -noname local0.debug "HMAC: HTTP_REQUEST: HMAC cookie is NOT verified using a cached HMAC token on TMM[TMM::cmp_unit]. Removing session cookie \"$static::session_cookie\" from current request."
HTTP::cookie remove $static::session_cookie
}
}]} then {
# log -noname local0.debug "HMAC: HTTP_REQUEST: The cache on TMM[TMM::cmp_unit] didn't contain a pre-computed HMAC value. Extracting received session_cookie and hmac_cookie values."
if { ( [set session_cookie [HTTP::cookie value $static::session_cookie]] ne "" ) and 
 ( [set hmac_cookie [HTTP::cookie value $static::hmac_cookie]] ne "" ) } then {
# log -noname local0.debug "HMAC: HTTP_REQUEST: The request contains the app cookie \"$static::session_cookie\" = \"$session_cookie\" and HMAC cookie \"$static::hmac_cookie\" = \"$hmac_cookie\"."
# log -noname local0.debug "HMAC: HTTP_REQUEST: Compute a fresh HMAC token for message \"$session_cookie:$hmac_input\" using Key \"$static::hmac_signing_key\"."
set hmac_token [b64encode [CRYPTO::sign -alg hmac-sha256 -key $static::hmac_signing_key "$session_cookie:$hmac_input"]]
# log -noname local0.debug "HMAC: HTTP_REQUEST: Compare the computed HMAC token \"$hmac_token\" with received HMAC cookie \"$static::hmac_cookie\" = \"$hmac_cookie\"."
if { $hmac_token eq $hmac_cookie } then {
# log -noname local0.debug "HMAC: HTTP_REQUEST: The HMAC cookie $static::hmac_cookie is verified using the computed HMAC token. Allowing the session cookie \"$static::session_cookie\" to pass."
if { [incr static::hmac_cache(count)] > $static::hmac_cache_maxsize } then {
# log -noname local0.debug "HMAC: HTTP_REQUEST: The HMAC cache has reached the maximum size of $static::hmac_cache_maxsize. Clearing the HMAC cache on TMM [TMM::cmp_unit]."
unset -nocomplain static::hmac_cache
set static::hmac_cache(count) 1
}
# log -noname local0.debug "HMAC: HTTP_REQUEST: Storing the computed HMAC token \"$hmac_token\" into the HMAC cache array."
set static::hmac_cache($session_cookie:$hmac_input) $hmac_token
} else {
# log -noname local0.debug "HMAC: HTTP_REQUEST: The HMAC cookie $static::hmac_cookie is NOT verified using the computed HMAC token. Removing session cookie \"$static::session_cookie\" from current request."
HTTP::cookie remove $static::session_cookie
}
} else {
# log -noname local0.debug "HMAC: HTTP_REQUEST: Current request didn't contain session_cookie and/or hmac_cookie values. Removing session cookie \"$static::session_cookie\" from current request."
HTTP::cookie remove $static::session_cookie
}
}
}
when HTTP_RESPONSE {
# log -noname local0.debug "HMAC: HTTP_RESPONSE: Checking if HTTP response sets the app cookie \"$static::session_cookie\"."
if { [set session_cookie [HTTP::cookie value $static::session_cookie]] ne "" } then {
# log -noname local0.debug "HMAC: HTTP_RESPONSE: The response contains the app cookie \"$static::session_cookie\" = \"$session_cookie\"."
if { [catch {
# log -noname local0.debug "HMAC: HTTP_RESPONSE: Inserting cached HMAC cookie \"$static::hmac_cookie\" = \"$static::hmac_cache($session_cookie:$hmac_input)\" to the response."
HTTP::header insert "Set-Cookie" "$static::hmac_cookie=$static::hmac_cache($session_cookie:$hmac_input); HttpOnly; Secure; Path=/"
}]} then {
# log -noname local0.debug "HMAC: HTTP_RESPONSE: The cache on TMM[TMM::cmp_unit] didn't contain a pre-computed HMAC value."
if { [incr static::hmac_cache(count)] > $static::hmac_cache_maxsize } then {
# log -noname local0.debug "HMAC: HTTP_RESPONSE: The HMAC cache has reached the maximum size of $static::hmac_cache_maxsize. Clearing the HMAC cache on TMM [TMM::cmp_unit]."
unset -nocomplain static::hmac_cache
set static::hmac_cache(count) 1
}
# log -noname local0.debug "HMAC: HTTP_RESPONSE: Compute a fresh HMAC token for message \"$session_cookie:$hmac_input\" using Key \"$static::hmac_signing_key\".
HTTP::header insert "Set-Cookie" "$static::hmac_cookie=[set static::hmac_cache($session_cookie:$hmac_input) [b64encode [CRYPTO::sign -alg hmac-sha256 -key $static::hmac_signing_key "$session_cookie:$hmac_input"]]]; HttpOnly; Secure; Path=/"
# log -noname local0.debug "HMAC: HTTP_RESPONSE: Inserting computed HMAC cookie \"$static::hmac_cookie\" = \"$static::hmac_cache($session_cookie:$hmac_input)\" to the response and storing the computed HMAC token into the HMAC cache array."
}
}
}

Tested this on version:

12.0
Updated Jun 06, 2023
Version 2.0

Was this article helpful?

No CommentsBe the first to comment